This is the first of three input files for this example

TITLE:
  Example 3 - Multiple Group Confirmatory Factor Analysis (Configural Invariance)

VARIABLE:
  NAMES ARE
  id wjcalc wjspl wratspl wratcalc waiscalc waisspl
  edlevel newschl suspend expelled haveld female age;

  USEVARIABLES ARE
  wratcalc wjcalc waiscalc wratspl wjspl waisspl;
  MISSING ARE all(99999);

There is one important addition in the VARIABLE command, the "GROUPING IS female (0=male 1=female);" line. This tells Mplus that the grouping variable is the female variable, all cases with a 0 on that variable are males, and all cases with a 1 on that variable are females. This must be included in order to conduct a multiple group analysis of any kind.

GROUPING IS female(0=male 1=female);

Here the user needs to specify two models, one for males and another for females. Entries under the "MODEL:" heading are for the male model, and entries under the "MODEL female:" portion are for the female model. In order to test for configural invariance with fixed-factor identification the latent variables are forced to have a mean of 0 and a variance of 1 for each group. The "[MATH@0 SPELL@0];" line is used to set the latent variable means to 0. This allows all measurement parameters (factor loadings, intercepts) to be freely estimated in each group with an identified model. The Mplus default is to constrain item intercepts across groups, this is overcome with the "[wratspl wjspl waisspl wratcalc wjcalc waiscalc];" line included for each model. These commands tell Mplus to estimate the intercepts for each group individually.

MODEL:
  MATH BY wratcalc* wjcalc waiscalc;
  SPELL BY wratspl* wjspl waisspl;
  [wratcalc wjcalc waiscalc wratspl wjspl waisspl];
  MATH@1 SPELL@1;
  [MATH@0 SPELL@0];

  MODEL female:
  MATH BY wratcalc* wjcalc waiscalc;
  SPELL BY wratspl* wjspl waisspl;
  [wratcalc wjcalc waiscalc wratspl wjspl waisspl];

Additional output can be requested.

OUTPUT:
  TECH1;
  STDYX;

Click cfa-01-1-configural.out to see the output.